<aside> <img src="/icons/star_blue.svg" alt="/icons/star_blue.svg" width="40px" /> If you’re building Ultimate Notes yourself, you can copy and paste the formulas below into the relevant properties.

</aside>

https://www.youtube.com/watch?v=zLqkp3-VLSM

Notes Formulas

Edited

(dateBetween(now(), prop("Last edited time"), "days") + "d").style("c","b","blue","blue_background")

Duration

prop("Duration (Seconds)").empty() ? "" : 
	lets(
		hour,
		floor(prop("Duration (Seconds)") / 3600),
		minute,
		floor((prop("Duration (Seconds)") % 3600) / 60),
		second,
		floor(prop("Duration (Seconds)") % 3600 % 60),
		[
			hour < 10 ? "0" + hour : hour,
			minute < 10 ? "0" + minute : minute,
			second < 10 ? "0" + second: second
		]
	).join(":")

Base URL

replace(prop("URL"), "([^/]*//)?(www\\.)?([^/]*).*", "$3")

Tags Formulas

Latest Note

prop("Notes").find(
	current.id() == prop("Notes").map(
		[
			let(
				stamp,
				current.prop("Last edited time").timestamp(),
				"0".repeat(15).substring(0,15 - stamp.length()) + stamp
			),
			current.id()
		]
	).sort().reverse().first().last()
)

Latest Note Date

prop("Notes").map(current.prop("Last edited time")).sort().reverse().first()

Note Count

lets(
	count,
	prop("Notes").length(),
	plural,
	count == 1 ? " " : "s",
	count + " Note" + plural
).style("c","b","blue","blue_background")